Calculations to accompany "Transfer Fee Regulations and Development of Talent"
Marko Terviö

Updated April 18th, 2005

Helpful Functions/Definitions

Dashed = Dashing[{0.01, 0.01}];
Dotted = Dashing[{0.003, 0.01}];
DiscreteMax[funk_, xmin_, xmax_, xsteps_] := 
      Module[{tabx, tempfunk}, 
        tabx = Table[{xi, funk[xi]}, {xi, xmin, 
              xmax, (xmax - xmin)/xsteps}]; 
        tempfunk = Interpolation[tabx]; gtab = tabx; 
        NMaximize[{tempfunk[x], 
            xmin ≤ x ≤  xmax}, {x}, 
          MaxIterations -> 1000, PrecisionGoal -> 10, 
          AccuracyGoal -> Infinity]]
Off[General::"spell1"]

Uniform distributions

Small market: b uniform in [1,β]
Large market: b uniform in [1,β+δ]
Talent: θ uniform in [0,α]

assums = {β > 1, δ > 0, α > 0, 1 > i > 0, 
          1 > z > 2/3};
Simp[x_] := FullSimplify[x, assums]

Profile, density, and  CDF of club size in autarky

b[i_, β_] := 1 + i (β - 1)
g[b_, β_] := 1/(β - 1)
Ng[b_, β_] := 
      If[b ≤ β, 1/(β - 1), 
        0]
G[b_, β_] := (b - 1)/(β - 
            1)
NG[b_, β_] := 
      If[b ≤ β, (b - 1)/(β - 1), 
        0]

bmean[β_] := ((1 + β)/2)

The Integrated market

GI[b_, β_, δ_] := (1/2) (Min[1, G[b, β]] + 
            Min[1, G[b, β + δ]])
ihat[β_, δ_] := GI[β, β, δ]

Simp[ihat[β, δ]]

Solving for the profile:

FullSimplify[
      b /. Solve[(1 + G[b, β + δ])/2 == i, b], 
      assums]
Collect[
      FullSimplify[
        b /. Solve[(G[b, β] + G[b, β + δ])/2 == 
              i, b], assums], i]

B1[i_, β_, δ_] := 
      1 + ((2 (β - 1) (β + δ - 
                    1) )/(2 ( β - 
                      1) + δ)) i 
B2[i_, β_, δ_] := 
      2 - β - δ + 
        2 (β - 1 + δ) i
B[i_, β_, δ_] := 
      If[i ≤  ihat[β, δ], B1[i, β, δ], 
        B2[i, β, δ]]

βx = 2; δx = 1;
Plot[{B[i, βx, δx], b[i, βx], 
        b[i, βx + δx]}, {i, 0, 1}, 
      PlotStyle -> {Dashed, Black, Red}, PlotRange -> All, 
      PlotPoints -> 100]
N[ihat[βx, δx]]

Simp[
      Limit[ihat[β, δ], δ -> Infinity]]

Talent

θ[i_, α_] := α  i
a[i_, z_, α_] := 
      If[i < z, 
        amean[α], θ[
          1 - ((1 - i)/z), α]]
fθ[a_, α_] := 
      If[a ≤  α, 1/α, 0]
Fθ[a_, α_] := a/α
amean[α_] := (α/2)
da[i_, z_, α_] := 
      If[i ≤ z, 0, (α/z)]

Analysis

Equilibrium z maximizes total surplus Y[z] = (∫_0^1) a[j | z] 
            b[j] dj=\(TraditionalForm\`θ\&_\)(∫_0^z) b[
            j] dj + (∫_z^1) a[j | z] 
          b[j] dj

Autarky

Total surplus:

Y[z_, α_, β_] := 
      amean[α] Integrate[b[i, β], {i, 0, z}] + 
        Integrate[
          b[i, β] θ[1 - ((1 - i)/z), α], {i, z, 
            1}]

Simp[D[Y[z, α, β], z]]

Factor α/(6  (z^2))  cancels out of the first-order condition ==> Maximizer independent of α.

foc[z_, β_] := 
      2 + β + 
        (z^2) (-9 + 7 z + 3 β - 7 z β)

First-order condition is a cubic, without a useful closed form solution.

Using the implicit function theorem to solve for the slope of z[β+δ]:

dFdz = 
        FullSimplify[D[foc[z, β + δ], z], 
          assums];
dFdδ = 
        FullSimplify[D[foc[z, β + δ], δ], 
          assums];
dZLdδ = FullSimplify[-dFdδ/dFdz, assums]

Integrated market (sufficiently small δ so that z<ihat)

Note that z must be at least (1/(2 - Fθ[amean[α], α])))=(2/3) while ihat[β,0]=1.

Total Surplus:

Yint[z_, α_, β_, δ_] := 
      amean[α] Integrate[B1[i, β, δ], {i, 0, z}] + 
        Integrate[θ[1 - ((1 - i)/z), α] 
            B1[i, β, δ], {i, z, ihat[β, δ]}] + 
        Integrate[θ[1 - ((1 - i)/z), α] 
            B2[i, β, δ], {i, ihat[β, δ], 
            1}]

Simp[Yint[z, α, β, δ]]
Simp[
      D[Yint[z, α, β, δ], z]]
Collect[%*(24  (z^2)/α), z]

Again, α canceled out. The first-order condition of total surplus maximization is (proportional to):

focInt[
        z_, β_, δ_] :=  -((56 (z^3) (-1 + β) (-1 + β + δ))/(-2 + 
                2 β + δ)) + ((4 (-2 + β + (β^2)) + 6 (1 + β) δ + (δ^2))/(-1 + β + δ)) + ((24 (z^2) (3 - 2 δ + β (-4 + β + δ)))/(-2 + 2 β + δ))

dfocIdz = 
        Simp[D[focInt[z, β, δ], 
            z]];
dfocIdδ = 
        Simp[D[focInt[
              z, β, δ], δ]];
dZIdδ = Simp[-dfocIdδ/dfocIdz]

The comparison of the slopes of ZL[δ] abd ZI[δ] as δ->0
(in Proof of Proposition 7)

Simp[dZLdδ /. δ -> 0]
Simp[dZIdδ /. δ -> 0]
Simp[(dZIdδ/dZLdδ) /. δ -> 0]

Numerical

Optimal z in autarky

zstar[β_] := 
      z /. NMaximize[{Y[z, 1, β], 1 > z > 2/3}, z, 
            MaxIterations -> 1000][[2]]

αx = 1; βx = 2;
Plot[Y[z, αx, βx], {z, 1/2, 1}]
zstar[βx]

Optimal z in the Integrated market

For general parameters (β>1,δ>0)  both of the cases z>ihat and z<ihat are possible.
Total surplus is:

NY[z_, α_, β_, δ_] := 
      If[z < ihat[β, δ], 
        Integrate[B1[i, β, δ], {i, 0, z}] amean[α] + 
          Integrate[θ[1 - (1 - i)/z, α] 
              B1[i, β, δ], {i, z, ihat[β, δ]}] + 
          Integrate[θ[1 - (1 - i)/z, α] 
              B2[i, β, δ], {i, ihat[β, δ], 1}], 
        Integrate[B1[i, β, δ], {i, 0, ihat[β, δ]}] 
            amean[α] + 
          Integrate[
            B2[i, β, δ] amean[α], {i, 
              ihat[β, δ], z}] + 
          Integrate[θ[1 - (1 - i)/z, α] 
              B2[i, β, δ], {i, z, 1}]]

To avoid any problems caused by the kink point at ihat, the optimization checks for maxima on both sides of ihat separately

ZBigStar[α_, β_, δ_] := 
      z /. NMaximize[{NY[z, α, β, δ], 1 > z > 2/3}, z, 
            MaxIterations -> 1000][[2]]
ZBigStarRobust[α_, β_, δ_] := 
      Module[{z1, z2, ix = ihat[β, δ]}, 
        If[ix  ≤ 2/3, ZBigStar[α, β, δ], 
          z1 = z /. NMaximize[{NY[z, α, β, δ], 
                    ix ≥  z > 2/3}, z, 
                  MaxIterations -> 
                    1000][[2]]; 
z2 = 
            z /. NMaximize[{NY[z, α, β, δ], 
                    1 >  z ≥  ix}, z, 
                  MaxIterations -> 
                    1000][[2]]; 
If[
            NY[z1, α, β, δ] > 
              NY[z2, α, β, δ], z1, z2]]]

βx = 2; δx = 1;
Plot[{b[i, βx + δx], B[i, βx, δx], 
        b[i, βx]}, {i, 0, 1}, PlotStyle -> {Black, Dashed, Red}, 
      PlotRange -> All, 
      PlotLabel -> "Profiles in the Large, Integrated, and Small \
market"]
ihat[βx, δx]

Plot[NY[z, αx, βx, δx], {z, 1/2, 1}]

Comparison of Large and Integrated market

Comparisons as a function of δ, with fixed β=2, α=1.

Solid lines: Large Market
Dashed lines: Integrated Market
(both are the same as the small market at δ=0)

Plot[{zstar[βx + δ], 
        ZBigStarRobust[αx, βx, δ]}, {δ, 0, 10}, 
      PlotStyle -> {Black, Dashed}]

Close-up for small δ

Plot[{zstar[βx + δ], 
        ZBigStarRobust[αx, βx, δ]}, {δ, 0, 0.5}, 
      PlotStyle -> {Black, Dashed}]

Caculation of optimal z is a little bit slow for the integrated market, so let's save the results

dmax = 5;
Timing[tempint = 
          Table[{δ, 
              ZBigStarRobust[αx, βx, δ]}, {δ, 
              0.05, dmax, 0.05}];]
tempint = 
        Join[{{0, zstar[βx]}}, tempint];
Zint[d_] := Interpolation[tempint, InterpolationOrder -> 1][
        d]

\(\(\(\ \)\(Expected\ transfer\ fees \((\(a\^*\) - θ\&_)\) \(b\^*\)\)\)\)

PL[β_] := (θ[2 - 1/zstar[β], αx] - 
            amean[αx]) 
        b[zstar[β], β]
PI[δ_] := (θ[2 - 1/Zint[δ], αx] - 
            amean[αx]) 
        B[Zint[δ], βx, δ]

Plot[{PL[βx + δ], PI[δ]}, {δ, 0, dmax}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "E[Transfer Fee], in Large and Integrated Market"]
Plot[{PL[βx + δ] - PI[δ]}, {δ, 0, 0.5}, 
      PlotRange -> All, 
      PlotLabel -> "Difference in Expected TFs, Large-Integrated"]

Plot[{b[zstar[βx + δ], βx + δ], 
        B[Zint[δ], βx, δ]}, {δ, 0, dmax}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "Threshold club size in Large and Integrated market\
"]

Transfer fee by quantile, given α,β,δ

a'[i|z] is α/z

PiL[j_, z_, α_, β_] := (α/z) 
        NIntegrate[b[i, β], {i, z, j}]
PiI[j_, zx_, α_, β_, δ_] := 
      If[ihat[β, δ] < zx, (α/zx) 
          NIntegrate[
            B2[i, β, δ], {i, zx, 
              j}], (α/zx) (NIntegrate[
                B1[i, β, δ], {i, zx, 
                  Min[j, ihat[β, δ]]}] + 
              If[ihat[β, δ] < j, 
                NIntegrate[
                  B2[i, β, δ], {i, ihat[β, δ], j}], 
                0])]

δx = 5;
{zLtemp = zstar[βx + δx], 
      zItemp = ZBigStarRobust[αx, βx, δx]}
Plot[{PiL[j, zLtemp, αx, βx + δx], 
        Max[PiI[j, zItemp, αx, βx, δx], 0]}, {j, zLtemp, 
        1}, PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, δ=5"]

δx = 0.1;
{zLtemp = zstar[βx + δx], 
      zItemp = ZBigStarRobust[αx, βx, δx]}
Plot[{Max[PiL[j, zLtemp, αx, βx + δx], 0], 
        PiI[j, zItemp, αx, βx, δx]}, {j, zItemp, 1}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, δ=0.1"]
Plot[{Max[PiL[j, zLtemp, αx, βx + δx], 0], 
        PiI[j, zItemp, αx, βx, δx]}, {j, zItemp,  .71}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "Profiles of Transfer Fees, δ=0.1, \
Close-up"]

Winners & Losers

Solid lines:Large market
Dashed lines:Integrated market
Red lines: Small market

Expected transfer fees

PL[α_, β_] := 
      Module[{zx = 
            zstar[β]}, (θ[2 - 1/zx, α] - 
              amean[α]) b[zx, β]]
PI[zx_, α_, δ_, β_] := (θ[
              2 - 1/zx, α] - amean[α]) 
        B[zx, β, δ]

Profiles of profit

ProfitL[j_, α_, β_] := 
      Module[{zx = zstar[β]}, 
        If[j < zx, 
          amean[α] b[j, β] + 
            PL[α, β], θ[1 - ((1 - j)/zx), α] 
              b[j, β] - 
            PiL[j, zx, α, β]]]
ProfitI[j_, zx_, α_, β_, δ_] := 
      If[j < zx, 
        amean[α] B[j, β, δ] + 
          PI[zx, α, δ, β], θ[
              1 - ((1 - j)/zx), α] B[j, β, δ] - 
          PiI[j, zx, α, β, δ]]

δx = 3;
zIx = 
        ZBigStarRobust[αx, βx, δx];
Plot[{ProfitL[j, αx, βx + δx], 
        ProfitI[j, zIx, αx, βx, δx], 
        ProfitL[j, αx, βx]}, {j, 0, 1}, 
      PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profiles of Profit"]
ParametricPlot[{{b[j, βx + δx], 
          ProfitL[j, αx, βx + δx]}, {B[
            j, βx, δx], 
          ProfitI[j, zIx, αx, βx, δx]}, {b[j, βx], 
          ProfitL[j, αx, βx]}}, {j, 0, 1}, 
      PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]

in the above case all small market clubs benefit from integration

δx = 0.4;
zIx = 
        ZBigStarRobust[αx, βx, δx];
Plot[{ProfitL[j, αx, βx + δx], 
        ProfitI[j, zIx, αx, βx, δx], 
        ProfitL[j, αx, βx]}, {j, 0, 1}, 
      PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profiles of Profit"]
ParametricPlot[{{b[j, βx + δx], 
          ProfitL[j, αx, βx + δx]}, {B[
            j, βx, δx], 
          ProfitI[j, zIx, αx, βx, δx]}, {b[j, βx], 
          ProfitL[j, αx, βx]}}, {j, 0, 1}, 
      PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]

In this case the biggest clubs in the small market lose out from integration

Power Law Distributions

This is probably the most realistic case
Density of club size proportional to (b^(-η))
Small market: support of b is [1,β]
Large market: support of b is [1,β+δ]
(same power η≥1 in both markets)

Density of talent proportional to (θ^(-ξ))
support is [1,α]

assums = {β > 1, δ > 0, η > 1, α > 
            1, ξ > 1, 1 > i > 0, 1 > z > 1/2};

Profile, density, and  CDF of club size in autarky

b[i_, η_, β_] := (((1 + ((β^(-(η - 1))) - 1) i))^(-(1/(η - 1))))
G[b_, η_, β_] := (((b^(-η)) (-b + (b^η)) (β^η))/(-β + (β^η)))
g[b_, η_, β_] := ((((((β/b)))^η) (-1 + η))/(-β + (β^η)))
NG[b_, η_, β_] := 
      If[b ≤ β, G[b, η, β], 
        1]
Ng[b_, η_, β_] := 
      If[b ≤ β, g[b, η, β], 
        0]
bmean[η_, β_] := ((((β^η) - β ((((β^(1 - η))))^((1/(1 - η))))) (η - 1))/(((β^η) - β) (η - 2)))

Plot[{b[i, 2, 2], b[i, 2, 3], b[i, 2, 4], b[i, 3, 2], b[i, 3, 3], 
        b[i, 3, 4]}, {i, 0, 1}, 
      PlotStyle -> {Black, Red, Blue, 
          Dashed, {Dashed, Red}, {Dashed, Blue}}]

The Integrated market

GI[b_, η_, β_, δ_] := (1/
            2) (Min[1, G[b, η, β]] + 
            Min[1, G[b, η, β + δ]])
ihat[η_, β_, δ_] := 
      (1/2) (1 + (((β - (β^η)) (((((β + δ)/β)))^η))/(β + δ - (((β + δ))^η))))

Solving for the profile:

Simp[
      b /. Solve[(1/2) (G[b, η, β] + 
                  G[b, η, β + δ]) == i, 
          b]]
Simp[
      b /. Solve[(1/2) (1 + 
                  G[b, η, β + δ]) == i, 
          b]]

B1[i_, η_, β_, δ_] := (((1 - ((2 i (-β + (β^η)) (β + δ - (((β + δ))^η)))/((β^η) (β + δ) + β (((β + δ))^η) - 2 (((β (β + δ)))^η)))))^((1/(1 - η))))
B2[i_, η_, β_, δ_] := (((2 - 2 i + (-1 + 2 i) (((β + δ))^(1 - η))))^((1/(1 - η))))
B[i_, η_, β_, δ_] := 
      If[i ≤  ihat[η, β, δ], 
        B1[i, η, β, δ], 
        B2[i, η, β, δ]]

Talent

θ[i_, ξ_, α_] := 
      b[i, ξ, α]
a[i_, z_, ξ_, α_] := 
      If[i < z, 
        amean[α, ξ], θ[
          1 - ((1 - i)/z), ξ, α]]
fθ[a_, ξ_, α_] := 
      g[a, ξ, α]
Fθ[a_, ξ_, α_] := 
      G[a, ξ, α]
amean[ξ_, α_] := 
      bmean[ξ, α]
zmin[ξ_, α_] := 
      (1/(2 - Fθ[amean[ξ, α], ξ, α]))

Simp[D[θ[1 - ((1 - i)/z), ξ, α], i]]

da[i_, 
        z_, ξ_, α_] := (((1 - (α^(1 - ξ))) (((1 - (((-1 + i + z) (α^(-ξ)) (-α + (α^ξ)))/z)))^((ξ/(1 - ξ)))))/(z (ξ - 1)))

Numerical

Equilibrium z maximizes total surplus Y[z] = (∫_0^1) a[j | z] 
            b[j] dj=\(TraditionalForm\`θ\&_\)(∫_0^z) b[
            j] dj + (∫_z^1) a[j | z] 
          b[j] dj

Autarky

Total surplus:

Y[z_, ξ_, α_, η_, β_] := 
      amean[ξ, α] Integrate[b[i, η, β], {i, 0, z}] + 
        Integrate[
          b[i, η, β] θ[
              1 - ((1 - i)/z), ξ, α], {i, z, 
            1}]
NY[z_, ξ_, α_, η_, β_] := 
      amean[ξ, α] 
          NIntegrate[b[i, η, β], {i, 0, z}, 
            MaxRecursion -> 25] + 
        NIntegrate[
          b[i, η, β] θ[
              1 - ((1 - i)/z), ξ, α], {i, z, 1}, 
          MaxRecursion -> 25]

Optimal z in autarky

zstar[ξ_, α_, η_, β_] := 
      z /. NMaximize[{Y[z, ξ, α, η, β], 
              1 > z > zmin[α, ξ]}, z, 
            MaxIterations -> 1000][[2]]
Nzstar[ξ_, α_, η_, β_] := 
      z /. NMaximize[{NY[z, ξ, α, η, β], 
              1 > z > zmin[α, ξ]}, z, 
            MaxIterations -> 1000][[2]]

ξx = 2.5; ηx = 2.5; αx = 5; βx = 
      3;
Plot[
      Y[z, ξx, αx, ηx, βx], {z, 
        zmin[αx, ξx], 1}]
zstar[ξx, αx, ηx, βx]

Optimal z in the Integrated market

Y[z_, ξ_, α_, η_, β_, δ_] := 
      If[z < ihat[η, β, δ], 
        Integrate[B1[i, η, β, δ], {i, 0, z}] 
            amean[ξ, α] + 
          Integrate[θ[1 - (1 - i)/z, ξ, α] 
              B1[i, η, β, δ], {i, z, 
              ihat[η, β, δ]}] + 
          Integrate[θ[1 - (1 - i)/z, ξ, α] 
              B2[i, η, β, δ], {i, 
              ihat[η, β, δ], 1}], 
        Integrate[
              B1[i, η, β, δ], {i, 0, 
                ihat[η, β, δ]}] amean[ξ, α] + 
          Integrate[
            B2[i, η, β, δ] amean[ξ, α], {i, 
              ihat[η, β, δ], z}] + 
          Integrate[θ[1 - (1 - i)/z, ξ, α] 
              B2[i, η, β, δ], {i, z, 
              1}]]

    
NY[z_, ξ_, α_, η_, β_, δ_] := 
      If[z < ihat[η, β, δ], 
        NIntegrate[B1[i, η, β, δ], {i, 0, z}, 
              MaxRecursion -> 25] amean[ξ, α] + 
          NIntegrate[θ[1 - (1 - i)/z, ξ, α] 
              B1[i, η, β, δ], {i, z, 
              ihat[η, β, δ]}, MaxRecursion -> 25] + 
          NIntegrate[θ[1 - (1 - i)/z, ξ, α] 
              B2[i, η, β, δ], {i, 
              ihat[η, β, δ], 1}, MaxRecursion -> 25], 
        NIntegrate[
              B1[i, η, β, δ], {i, 0, 
                ihat[η, β, δ]}, MaxRecursion -> 25] 
            amean[ξ, α] + 
          NIntegrate[
            B2[i, η, β, δ] amean[ξ, α], {i, 
              ihat[η, β, δ], z}, MaxRecursion -> 25] + 
          NIntegrate[θ[1 - (1 - i)/z, ξ, α] 
              B2[i, η, β, δ], {i, z, 1}, 
            MaxRecursion -> 25]]

δx = 1;
Plot[
      NY[z, ξx, αx, ηx, βx, δx], {z, 
        zmin[αx, ξx], 1}]

ZBigStar[ξ_, α_, η_, β_, δ_] := 
      z /. NMaximize[{NY[z, ξ, α, η, β, δ], 
              1 > z > zmin[α, ξ]}, z, 
            MaxIterations -> 1000][[2]]
ZBigStarRobust[ξ_, α_, η_, β_, δ_] := 
      Module[{z1, z2, ix = ihat[η, β, δ]}, 
        If[ix  ≤ zmin[α, ξ], 
          ZBigStar[ξ, α, η, β, δ], 
          z1 = z /. NMaximize[{NY[
                      z, ξ, α, η, β, δ], 
                    ix ≥  z > zmin[α, ξ]}, z, 
                  MaxIterations -> 
                    1000][[2]]; 
z2 = 
            z /. NMaximize[{NY[
                      z, ξ, α, η, β, δ], 
                    1 >  z ≥  ix}, z, 
                  MaxIterations -> 
                    1000][[2]]; 
If[
            NY[z1, ξ, α, η, β, δ] > 
              NY[z2, ξ, α, η, β, δ], z1, 
            z2]]]

Timing[
      zstar[ξx, αx, ηx, βx + δx]]
Timing[
      Nzstar[ξx, αx, ηx, βx + δx]]
Timing[
      ZBigStar[ξx, αx, ηx, βx, δx]]

Off[NIntegrate::"nlim"]

δx = 5;
Plot[{b[i, ηx, βx + δx], 
        B[i, ηx, βx, δx], b[i, ηx, βx]}, {i, 0, 
        1}, PlotStyle -> {Black, Dashed, Red}, PlotRange -> All, 
      PlotLabel -> "Profiles in the Large, Integrated, and Small \
market"]
ihat[ηx, βx, δx]

Comparison of Large and Integrated market

Comparisons as a function of δ, with other parameters fixed

ξx = 2.5; ηx = 2.5; αx = 5; βx = 3;

Solid lines: Large Market
Dashed lines: Integrated Market
(both are the same as the small market at δ=0)

dmax = 10;
Timing[tempint = 
          Table[{δ, 
              ZBigStarRobust[ξx, αx, ηx, βx, δ]}, {δ, 0.05, dmax, 0.05}];]
tempint = 
        Join[{{0, Nzstar[ξx, αx, ηx, βx]}}, 
          tempint];
Zint[d_] := Interpolation[tempint, InterpolationOrder -> 1][
        d]

Timing[tempint2 = 
          Table[{δ, 
              Nzstar[ξx, αx, ηx, βx + δ]}, {δ, 0, dmax, 0.05}];]
ZLarge[d_] := Interpolation[tempint2, InterpolationOrder -> 1][
        d]

Plot[{Zint[d], ZLarge[d]}, {d, 0, dmax}, 
      PlotStyle -> {Dashed, Black}]

{Nzstar[ξx, αx, ηx, βx + 100], 
      ZBigStarRobust[ξx, αx, ηx, βx, 100]}

\(\(\(\ \)\(Expected\ transfer\ fees \((\(a\^*\) - θ\&_)\) \(b\^*\)\)\)\)

PL[δ_] := (θ[
              2 - 1/ZLarge[δ], ξx, αx] - 
            amean[ξx, αx]) 
        b[ZLarge[δ], ηx, βx + δ]
PI[δ_] := (θ[2 - 1/Zint[δ], ξx, αx] - 
            amean[ξx, αx]) 
        B[Zint[δ], ηx, βx, δ]

Plot[{PL[δ], PI[δ]}, {δ, 0, dmax}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "E[Transfer Fee], in Large and Integrated Market"]
Plot[{PL[δ] - PI[δ]}, {δ, 0, 0.5}, 
      PlotRange -> All, 
      PlotLabel -> "Difference in Expected TFs, Large-Integrated"]

Plot[{b[ZLarge[δ], ηx, βx + δ], 
        B[Zint[δ], ηx, βx, δ]}, {δ, 0, dmax}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "Threshold club size in Large and Integrated market\
"]

Transfer fee by quantile, given α,β,δ

PiL[j_, z_, ξ_, α_, η_, β_] := 
      NIntegrate[
        da[i, z, ξ, α] b[i, η, β], {i, z, 
          j}]
PiI[j_, zx_, ξ_, α_, η_, β_, δ_] := 
      If[ihat[η, β, δ] < zx, 
        NIntegrate[
          da[i, zx, ξ, α] B2[i, η, β, δ], {i, 
            zx, j}], (NIntegrate[
              da[i, zx, ξ, α] B1[
                  i, η, β, δ], {i, zx, 
                Min[j, ihat[η, β, δ]]}] + 
            If[ihat[η, β, δ] < j, 
              NIntegrate[
                da[i, zx, ξ, α] B2[
                    i, η, β, δ], {i, 
                  ihat[η, β, δ], j}], 0])]

δx = 2;
{zLtemp = Nzstar[ξx, αx, ηx, βx + δx], 
      zItemp = ZBigStarRobust[ξx, αx, ηx, βx, δx]}
Plot[{PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
        Max[PiI[j, zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, zLtemp, 1}, PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, δ=2"]
Plot[{Max[
          PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
          0], Max[PiI[j, 
            zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, Min[zLtemp, zItemp], Max[zLtemp, zItemp] + 0.01}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, δ=2, \
close-up"]

δx = 0.5;
{zLtemp = Nzstar[ξx, αx, ηx, βx + δx], 
      zItemp = ZBigStarRobust[ξx, αx, ηx, βx, δx]}
Plot[{Max[
          PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
          0], Max[PiI[j, 
            zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, Min[zLtemp, zItemp], 1}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees"]
Plot[{Max[
          PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
          0], Max[PiI[j, 
            zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, Min[zLtemp, zItemp], zLtemp + 0.01}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, Close-up"]

Winners & Losers

Solid lines:Large market
Dashed lines:Integrated market
Red lines: Small market

Expected transfer fees

PL[zx_, ξ_, α_, η_, β_] := (θ[
              2 - 1/zx, ξ, α] - amean[ξ, α]) 
        b[zx, η, β]
PI[zx_, ξ_, α_, η_, β_, δ_] := (θ[
              2 - 1/zx, ξ, α] - amean[ξ, α]) 
        B[zx, η, β, δ]

Profiles of profit

ProfitL[j_, zx_, ξ_, α_, η_, β_] := 
      If[j < zx, 
        amean[ξ, α] b[j, η, β] + 
          PL[zx, ξ, α, η, β], θ[
              1 - ((1 - j)/zx), ξ, α] b[j, η, β] - 
          PiL[j, zx, ξ, α, η, β]]
ProfitI[j_, zx_, ξ_, α_, η_, β_, δ_] := 
      If[j < zx, 
        amean[ξ, α] B[j, η, β, δ] + 
          PI[zx, ξ, α, η, β, δ], θ[
              1 - ((1 - j)/zx), ξ, α] 
            B[j, η, β, δ] - 
          PiI[j, zx, ξ, α, η, β, δ]]

δx = 2;
{zLx = Nzstar[ξx, αx, ηx, βx + δx], 
      zIx = ZBigStarRobust[ξx, αx, ηx, βx, δx], 
      zSx = Nzstar[ξx, αx, ηx, βx]}
Plot[{ProfitL[j, 
          zLx, ξx, αx, ηx, βx + δx], 
        ProfitI[j, zIx, ξx, αx, ηx, βx, δx], 
        ProfitL[j, zSx, ξx, αx, ηx, βx]}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profiles of Profit"]
ParametricPlot[{{b[j, ηx, βx + δx], 
          ProfitL[j, 
            zLx, ξx, αx, ηx, βx + δx]}, {B[
            j, ηx, βx, δx], 
          ProfitI[j, 
            zIx, ξx, αx, ηx, βx, δx]}, {b[
            j, ηx, βx], 
          ProfitL[j, zSx, ξx, αx, ηx, βx]}}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]

δx = 10;
{zLx = Nzstar[ξx, αx, ηx, βx + δx], 
      zIx = ZBigStarRobust[ξx, αx, ηx, βx, δx], 
      zSx = Nzstar[ξx, αx, ηx, βx]}
Plot[{ProfitL[j, 
          zLx, ξx, αx, ηx, βx + δx], 
        ProfitI[j, zIx, ξx, αx, ηx, βx, δx], 
        ProfitL[j, zSx, ξx, αx, ηx, βx]}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profiles of Profit"]
ParametricPlot[{{b[j, ηx, βx + δx], 
          ProfitL[j, 
            zLx, ξx, αx, ηx, βx + δx]}, {B[
            j, ηx, βx, δx], 
          ProfitI[j, 
            zIx, ξx, αx, ηx, βx, δx]}, {b[
            j, ηx, βx], 
          ProfitL[j, zSx, ξx, αx, ηx, βx]}}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]

Different numbers: η=1.5

ξx = 2.5; ηx = 1.5; αx = 5; βx = 3;

dmax = 10;
Timing[tempint = 
          Table[{δ, 
              ZBigStarRobust[ξx, αx, ηx, βx, δ]}, {δ, 0.05, dmax, 0.05}];]
tempint = 
        Join[{{0, Nzstar[ξx, αx, ηx, βx]}}, 
          tempint];
Zint[d_] := Interpolation[tempint, InterpolationOrder -> 1][
        d]
Timing[tempint2 = 
          Table[{δ, 
              Nzstar[ξx, αx, ηx, βx + δ]}, {δ, 0, dmax, 0.05}];]
ZLarge[d_] := Interpolation[tempint2, InterpolationOrder -> 1][
        d]

Plot[{Zint[d], ZLarge[d]}, {d, 0, dmax}, 
      PlotStyle -> {Dashed, Black}, 
      PlotLabel -> "Proportion of Novices"]
Plot[{Zint[d], ZLarge[d]}, {d, 0, 1.5}, 
      PlotStyle -> {Dashed, Black}, 
      PlotLabel -> "Proportion of Novices, Close-up"]
Plot[{PL[δ], PI[δ]}, {δ, 0, dmax}, 
      PlotStyle -> {Black, Dashed}, PlotRange -> All, 
      PlotLabel -> "E[Transfer Fee]"]
Plot[{PL[δ] - PI[δ]}, {δ, 0, 0.5}, 
      PlotRange -> All, 
      PlotLabel -> "Difference in Expected TFs, Large-Integrated"]

δx = 3;
{zLtemp = Nzstar[ξx, αx, ηx, βx + δx], 
      zItemp = ZBigStarRobust[ξx, αx, ηx, βx, δx]}
Plot[{PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
        Max[PiI[j, zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, zLtemp, 1}, PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees"]
Plot[{Max[
          PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
          0], Max[PiI[j, 
            zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, Min[zLtemp, zItemp], Max[zLtemp, zItemp] + 0.1}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees, close-up"]
ParametricPlot[{{b[j, ηx, βx + δx], 
          ProfitL[j, 
            zLx, ξx, αx, ηx, βx + δx]}, {B[
            j, ηx, βx, δx], 
          ProfitI[j, 
            zIx, ξx, αx, ηx, βx, δx]}, {b[
            j, ηx, βx], 
          ProfitL[j, zSx, ξx, αx, ηx, βx]}}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]

δx = 0.5;
{zLtemp = Nzstar[ξx, αx, ηx, βx + δx], 
      zItemp = ZBigStarRobust[ξx, αx, ηx, βx, δx]}
Plot[{PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
        Max[PiI[j, zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, zLtemp, 1}, PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees"]
Plot[{Max[
          PiL[j, zLtemp, ξx, αx, ηx, βx + δx], 
          0], Max[PiI[j, 
            zItemp, ξx, αx, ηx, βx, δx], 
          0]}, {j, Min[zLtemp, zItemp], Max[zLtemp, zItemp] + 0.01}, 
      PlotStyle -> {Black, Dashed}, 
      PlotLabel -> "Profiles of Transfer Fees,close-up"]
ParametricPlot[{{b[j, ηx, βx + δx], 
          ProfitL[j, 
            zLx, ξx, αx, ηx, βx + δx]}, {B[
            j, ηx, βx, δx], 
          ProfitI[j, 
            zIx, ξx, αx, ηx, βx, δx]}, {b[
            j, ηx, βx], 
          ProfitL[j, zSx, ξx, αx, ηx, βx]}}, {j, 0, 1}, 
      PlotRange -> All, PlotStyle -> {Black, Dashed, Red}, 
      PlotLabel -> "Profit as a function of b"]